perlrequick - Perl regular expressions quick start

This page covers the very basics of understanding, creating and using regular expressions ('regexes') in Perl.

The simplest regex is simply a word, or more generally, a string of characters. A regex consisting of a word matches any string that contains that word:

    "Hello World" =~ /World/;  # matches

In this statement, CWWorld is a regex and the CW// enclosing CW/World/ tells perl to search a string for a match. The operator CW=~ associates the string with the regex match and produces a true value if the regex matched, or false if the regex did not match. In our case, CWWorld matches the second word in CW"Hello World", so the expression is true. This idea has several variations.

Expressions like this are useful in conditionals:

    print "It matches\n" if "Hello World" =~ /World/;

The sense of the match can be reversed by using CW!~ operator:

    print "It doesn't match\n" if "Hello World" !~ /World/;

The literal string in the regex can be replaced by a variable:

    $greeting = "World";
    print "It matches\n" if "Hello World" =~ /$greeting/;

If you're matching against CW$_, the CW$_ =~ part can be omitted:

    $_ = "Hello World";
    print "It matches\n" if /World/;

Finally, the CW// default delimiters for a match can be changed to arbitrary delimiters by putting an CW'm' out front:

    "Hello World" =~ m!World!;   # matches, delimited by '!'
    "Hello World" =~ m{World};   # matches, note the matching '{}'
    "/usr/bin/perl" =~ m"/perl"; # matches after '/usr/bin',
                                 # '/' becomes an ordinary char

Regexes must match a part of the string exactly in order for the statement to be true:

    "Hello World" =~ /world/;  # doesn't match, case sensitive
    "Hello World" =~ /o W/;    # matches, ' ' is an ordinary char
    "Hello World" =~ /World /; # doesn't match, no ' ' at end

perl will always match at the earliest possible point in the string:

    "Hello World" =~ /o/;       # matches 'o' in 'Hello'
    "That hat is red" =~ /hat/; # matches 'hat' in 'That'

Not all characters can be used 'as is' in a match. Some characters, called metacharacters, are reserved for use in regex notation. The metacharacters are

    {}[]()^$.|*+?\

A metacharacter can be matched by putting a backslash before it:

    "2+2=4" =~ /2+2/;    # doesn't match, + is a metacharacter
    "2+2=4" =~ /2\+2/;   # matches, \+ is treated like an ordinary +
    'C:\WIN32' =~ /C:\\WIN/;                       # matches
    "/usr/bin/perl" =~ /\/usr\/bin\/perl/;  # matches

In the last regex, the forward slash CW'/' is also backslashed, because it is used to delimit the regex.

Non-printable ASCII characters are represented by escape sequences. Common examples are CW\t for a tab, CW\n for a newline, and CW\r for a carriage return. Arbitrary bytes are represented by octal escape sequences, e.g., CW\033, or hexadecimal escape sequences, e.g., CW\x1B:

    "1000\t2000" =~ m(0\t2)        # matches
    "cat"        =~ /\143\x61\x74/ # matches, but a weird way to spell cat

Regexes are treated mostly as double quoted strings, so variable substitution works:

    $foo = 'house';
    'cathouse' =~ /cat$foo/;   # matches
    'housecat' =~ /${foo}cat/; # matches

With all of the regexes above, if the regex matched anywhere in the string, it was considered a match. To specify where it should match, we would use the anchor metacharacters CW^ and CW$. The anchor CW^ means match at the beginning of the string and the anchor CW$ means match at the end of the string, or before a newline at the end of the string. Some examples:

    "housekeeper" =~ /keeper/;         # matches
    "housekeeper" =~ /^keeper/;        # doesn't match
    "housekeeper" =~ /keeper$/;        # matches
    "housekeeper\n" =~ /keeper$/;      # matches
    "housekeeper" =~ /^housekeeper$/;  # matches

A character class allows a set of possible characters, rather than just a single character, to match at a particular point in a regex. Character classes are denoted by brackets CW[...], with the set of characters to be possibly matched inside. Here are some examples:

    /cat/;            # matches 'cat'
    /[bcr]at/;        # matches 'bat', 'cat', or 'rat'
    "abc" =~ /[cab]/; # matches 'a'

In the last statement, even though CW'c' is the first character in the class, the earliest point at which the regex can match is CW'a'.

    /[yY][eE][sS]/; # match 'yes' in a case-insensitive way
                    # 'yes', 'Yes', 'YES', etc.
    /yes/i;         # also match 'yes' in a case-insensitive way

The last example shows a match with an CW'i' modifier, which makes the match case-insensitive.

Character classes also have ordinary and special characters, but the sets of ordinary and special characters inside a character class are different than those outside a character class. The special characters for a character class are CW-]\^$ and are matched using an escape:

   /[\]c]def/; # matches ']def' or 'cdef'
   $x = 'bcr';
   /[$x]at/;   # matches 'bat, 'cat', or 'rat'
   /[\$x]at/;  # matches '$at' or 'xat'
   /[\\$x]at/; # matches '\at', 'bat, 'cat', or 'rat'

The special character CW'-' acts as a range operator within character classes, so that the unwieldy CW[0123456789] and CW[abc...xyz] become the svelte CW[0-9] and CW[a-z]:

    /item[0-9]/;  # matches 'item0' or ... or 'item9'
    /[0-9a-fA-F]/;  # matches a hexadecimal digit

If CW'-' is the first or last character in a character class, it is treated as an ordinary character.

The special character CW^ in the first position of a character class denotes a negated character class, which matches any character but those in the brackets. Both CW[...] and CW[^...] must match a character, or the match fails. Then

    /[^a]at/;  # doesn't match 'aat' or 'at', but matches
               # all other 'bat', 'cat, '0at', '%at', etc.
    /[^0-9]/;  # matches a non-numeric character
    /[a^]at/;  # matches 'aat' or '^at'; here '^' is ordinary

Perl has several abbreviations for common character classes:

•

\d is a digit and represents

    [0-9]

•

\s is a whitespace character and represents

    [\ \t\r\n\f]

•

\w is a word character (alphanumeric or _) and represents

    [0-9a-zA-Z_]

•

\D is a negated \d; it represents any character but a digit

    [^0-9]

•

\S is a negated \s; it represents any non-whitespace character

    [^\s]

•

\W is a negated \w; it represents any non-word character

    [^\w]

•

The period '.' matches any character but \n

The CW\d\s\w\D\S\W abbreviations can be used both inside and outside of character classes. Here are some in use:

    /\d\d:\d\d:\d\d/; # matches a hh:mm:ss time format
    /[\d\s]/;         # matches any digit or whitespace character
    /\w\W\w/;         # matches a word char, followed by a
                      # non-word char, followed by a word char
    /..rt/;           # matches any two chars, followed by 'rt'
    /end\./;          # matches 'end.'
    /end[.]/;         # same thing, matches 'end.'

The word anchor CW\b matches a boundary between a word character and a non-word character CW\w\W or CW\W\w:

    $x = "Housecat catenates house and cat";
    $x =~ /\bcat/;  # matches cat in 'catenates'
    $x =~ /cat\b/;  # matches cat in 'housecat'
    $x =~ /\bcat\b/;  # matches 'cat' at end of string

In the last example, the end of the string is considered a word boundary.

We can match different character strings with the alternation metacharacter CW'|'. To match CWdog or CWcat, we form the regex CWdog|cat. As before, perl will try to match the regex at the earliest possible point in the string. At each character position, perl will first try to match the first alternative, CWdog. If CWdog doesn't match, perl will then try the next alternative, CWcat. If CWcat doesn't match either, then the match fails and perl moves to the next position in the string. Some examples:

    "cats and dogs" =~ /cat|dog|bird/;  # matches "cat"
    "cats and dogs" =~ /dog|cat|bird/;  # matches "cat"

Even though CWdog is the first alternative in the second regex, CWcat is able to match earlier in the string.

    "cats"          =~ /c|ca|cat|cats/; # matches "c"
    "cats"          =~ /cats|cat|ca|c/; # matches "cats"

At a given character position, the first alternative that allows the regex match to succeed will be the one that matches. Here, all the alternatives match at the first string position, so the first matches.

The grouping metacharacters CW() allow a part of a regex to be treated as a single unit. Parts of a regex are grouped by enclosing them in parentheses. The regex CWhouse(cat|keeper) means match CWhouse followed by either CWcat or CWkeeper. Some more examples are

    /(a|b)b/;    # matches 'ab' or 'bb'
    /(^a|b)c/;   # matches 'ac' at start of string or 'bc' anywhere

    /house(cat|)/;  # matches either 'housecat' or 'house'
    /house(cat(s|)|)/;  # matches either 'housecats' or 'housecat' or
                        # 'house'.  Note groups can be nested.

    "20" =~ /(19|20|)\d\d/;  # matches the null alternative '()\d\d',
                             # because '20\d\d' can't match

The grouping metacharacters CW() also allow the extraction of the parts of a string that matched. For each grouping, the part that matched inside goes into the special variables CW$1, CW$2, etc. They can be used just as ordinary variables:

    # extract hours, minutes, seconds
    $time =~ /(\d\d):(\d\d):(\d\d)/;  # match hh:mm:ss format
    $hours = $1;
    $minutes = $2;
    $seconds = $3;

In list context, a match CW/regex/ with groupings will return the list of matched values CW($1,$2,...). So we could rewrite it as

    ($hours, $minutes, $second) = ($time =~ /(\d\d):(\d\d):(\d\d)/);

If the groupings in a regex are nested, CW$1 gets the group with the leftmost opening parenthesis, CW$2 the next opening parenthesis, etc. For example, here is a complex regex and the matching variables indicated below it:

    /(ab(cd|ef)((gi)|j))/;
     1  2      34

Associated with the matching variables CW$1, CW$2, ... are the backreferences CW\1, CW\2, ... Backreferences are matching variables that can be used inside a regex:

    /(\w\w\w)\s\1/; # find sequences like 'the the' in string

CW$1, CW$2, ... should only be used outside of a regex, and CW\1, CW\2, ... only inside a regex.

The quantifier metacharacters CW?, CW*, CW+, and CW{} allow us to determine the number of repeats of a portion of a regex we consider to be a match. Quantifiers are put immediately after the character, character class, or grouping that we want to specify. They have the following meanings:

•

CWa? = match 'a' 1 or 0 times

•

CWa* = match 'a' 0 or more times, i.e., any number of times

•

CWa+ = match 'a' 1 or more times, i.e., at least once

•

CWa{n,m} = match at least CWn times, but not more than CWm times.

•

CWa{n,} = match at least CWn or more times

•

CWa{n} = match exactly CWn times

Here are some examples:

    /[a-z]+\s+\d*/;  # match a lowercase word, at least some space, and
                     # any number of digits
    /(\w+)\s+\1/;    # match doubled words of arbitrary length
    $year =~ /\d{2,4}/;  # make sure year is at least 2 but not more
                         # than 4 digits
    $year =~ /\d{4}|\d{2}/;    # better match; throw out 3 digit dates

These quantifiers will try to match as much of the string as possible, while still allowing the regex to match. So we have

    $x = 'the cat in the hat';
    $x =~ /^(.*)(at)(.*)$/; # matches,
                            # $1 = 'the cat in the h'
                            # $2 = 'at'
                            # $3 = ''   (0 matches)

The first quantifier CW.* grabs as much of the string as possible while still having the regex match. The second quantifier CW.* has no string left to it, so it matches 0 times.

There are a few more things you might want to know about matching operators. In the code

    $pattern = 'Seuss';
    while (<>) {
        print if /$pattern/;
    }

perl has to re-evaluate CW$pattern each time through the loop. If CW$pattern won't be changing, use the CW//o modifier, to only perform variable substitutions once. If you don't want any substitutions at all, use the special delimiter CWm'':

    @pattern = ('Seuss');
    m/@pattern/; # matches 'Seuss'
    m'@pattern'; # matches the literal string '@pattern'

The global modifier CW//g allows the matching operator to match within a string as many times as possible. In scalar context, successive matches against a string will have CW//g jump from match to match, keeping track of position in the string as it goes along. You can get or set the position with the CWpos() function. For example,

    $x = "cat dog house"; # 3 words
    while ($x =~ /(\w+)/g) {
        print "Word is $1, ends at position ", pos $x, "\n";
    }

prints

    Word is cat, ends at position 3
    Word is dog, ends at position 7
    Word is house, ends at position 13

A failed match or changing the target string resets the position. If you don't want the position reset after failure to match, add the CW//c, as in CW/regex/gc.

In list context, CW//g returns a list of matched groupings, or if there are no groupings, a list of matches to the whole regex. So

    @words = ($x =~ /(\w+)/g);  # matches,
                                # $word[0] = 'cat'
                                # $word[1] = 'dog'
                                # $word[2] = 'house'

Search and replace is performed using CWs/regex/replacement/modifiers. The CWreplacement is a Perl double quoted string that replaces in the string whatever is matched with the CWregex. The operator CW=~ is also used here to associate a string with CWs///. If matching against CW$_, the CW$_ =~ can be dropped. If there is a match, CWs/// returns the number of substitutions made, otherwise it returns false. Here are a few examples:

    $x = "Time to feed the cat!";
    $x =~ s/cat/hacker/;   # $x contains "Time to feed the hacker!"
    $y = "'quoted words'";
    $y =~ s/^'(.*)'$/$1/;  # strip single quotes,
                           # $y contains "quoted words"

With the CWs/// operator, the matched variables CW$1, CW$2, etc. are immediately available for use in the replacement expression. With the global modifier, CWs///g will search and replace all occurrences of the regex in the string:

    $x = "I batted 4 for 4";
    $x =~ s/4/four/;   # $x contains "I batted four for 4"
    $x = "I batted 4 for 4";
    $x =~ s/4/four/g;  # $x contains "I batted four for four"

The evaluation modifier CWs///e wraps an CWeval{...} around the replacement string and the evaluated result is substituted for the matched substring. Some examples:

    # reverse all the words in a string
    $x = "the cat in the hat";
    $x =~ s/(\w+)/reverse $1/ge;   # $x contains "eht tac ni eht tah"

    # convert percentage to decimal
    $x = "A 39% hit rate";
    $x =~ s!(\d+)%!$1/100!e;       # $x contains "A 0.39 hit rate"

The last example shows that CWs/// can use other delimiters, such as CWs!!! and CWs{}{}, and even CWs{}//. If single quotes are used CWs''', then the regex and replacement are treated as single quoted strings.

CWsplit /regex/, string splits CWstring into a list of substrings and returns that list. The regex determines the character sequence that CWstring is split with respect to. For example, to split a string into words, use

    $x = "Calvin and Hobbes";
    @word = split /\s+/, $x;  # $word[0] = 'Calvin'
                              # $word[1] = 'and'
                              # $word[2] = 'Hobbes'

To extract a comma-delimited list of numbers, use

    $x = "1.618,2.718,   3.142";
    @const = split /,\s*/, $x;  # $const[0] = '1.618'
                                # $const[1] = '2.718'
                                # $const[2] = '3.142'

If the empty regex CW// is used, the string is split into individual characters. If the regex has groupings, then the list produced contains the matched substrings from the groupings as well:

    $x = "/usr/bin";
    @parts = split m!(/)!, $x;  # $parts[0] = ''
                                # $parts[1] = '/'
                                # $parts[2] = 'usr'
                                # $parts[3] = '/'
                                # $parts[4] = 'bin'

Since the first character of CW$x matched the regex, CWsplit prepended an empty initial element to the list.

None.

This is just a quick start guide. For a more in-depth tutorial on regexes, see perlretut and for the reference page, see perlre.

Copyright (c) 2000 Mark Kvale All rights reserved.

This document may be distributed under the same terms as Perl itself.

The author would like to thank Mark-Jason Dominus, Tom Christiansen, Ilya Zakharevich, Brad Hughes, and Mike Giroux for all their helpful comments.