APR::Table - Perl API for manipulating APR opaque string-content tables

  use APR::Table ();

  $table = APR::Table::make($pool, $nelts);
  $table_copy = $table->copy($pool);

  $table->clear();

  $table->set($key => $val);
  $table->unset($key);
  $table->add($key, $val);

  $val = $table->get($key);
  @val = $table->get($key);

  $table->merge($key => $val);

  use APR::Const -compile qw(:table);
  $table_overlay = $table_base->overlay($table_overlay, $pool);
  $table_overlay->compress(APR::Const::OVERLAP_TABLES_MERGE);

  $table_a->overlap($table_b, APR::Const::OVERLAP_TABLES_SET);

  $table->do(sub {print "key $_[0], value $_[1]\n"}, @valid_keys);

  #Tied Interface
  $value = $table->{$key};
  $table->{$key} = $value;
  print "got it" if exists $table->{$key};

  foreach my $key (keys %{$table}) {
      print "$key = $table->{$key}\n";
  }

CWAPR::Table allows its users to manipulate opaque string-content tables.

On the C level the opaque string-content means: you can put in '\0'-terminated strings and whatever you put in your get out.

On the Perl level that means that we convert scalars into strings and store those strings. Any special information that was in the Perl scalar is not stored. So for example if a scalar was marked as utf8, tainted or tied, that information is not stored. When you get the data back as a Perl scalar you get only the string.

The table's structure is somewhat similar to the Perl's hash structure, but allows multiple values for the same key. An access to the records stored in the table always requires a key.

The key-value pairs are stored in the order they are added.

The keys are case-insensitive.

However as of the current implementation if more than value for the same key is requested, the whole table is lineary searched, which is very inefficient unless the table is very small.

CWAPR::Table provides a TIE Interface.

See apr/include/apr_tables.h in ASF's apr project for low level details.

CWAPR::Table provides the following functions and/or methods: Add data to a table, regardless of whether there is another element with the same key.

  $table->add($key, $val);

ret: no return value

since: 2.0.00

When adding data, this function makes a copy of both the key and the value. Delete all of the elements from a table.

  $table->clear();

ret: no return value

since: 2.0.00

Eliminate redundant entries in a table by either overwriting or merging duplicates:

  $table->compress($flags);

  APR::Const::OVERLAP_TABLES_MERGE -- to merge
  APR::Const::OVERLAP_TABLES_SET   -- to overwrite

ret: no return value

since: 2.0.00

Converts multi-valued keys in CW$table into single-valued keys. This function takes duplicate table entries and flattens them into a single entry. The flattening behavior is controlled by the (mandatory) CW$flags argument.

When CW$flags == CWAPR::Const::OVERLAP_TABLES_SET, each key will be set to the last value seen for that key. For example, given key/value pairs 'foo => bar' and 'foo => baz', 'foo' would have a final value of 'baz' after compression the 'bar' value would be lost.

When CW$flags == CWAPR::Const::OVERLAP_TABLES_MERGE, multiple values for the same key are flattened into a comma-separated list. Given key/value pairs 'foo => bar' and 'foo => baz', 'foo' would have a final value of 'bar, baz' after compression.

Access the constants via:

  use APR::Const -compile qw(:table);

or an explicit:

  use APR::Const -compile qw(OVERLAP_TABLES_SET OVERLAP_TABLES_MERGE);

CWcompress() combined with CWCIoverlay()CW does the same thing as CWCIoverlap()CW.

Examples: Start with table CW$table:

  foo => "one"
  foo => "two"
  foo => "three"
  bar => "beer"

  use APR::Const    -compile => ':table';
  my $table = APR::Table::make($r->pool, TABLE_SIZE);

  $table->set(bar => 'beer');
  $table->set(foo => 'one');
  $table->add(foo => 'two');
  $table->add(foo => 'three');

  $table->compress(APR::Const::OVERLAP_TABLES_SET);

  foo => "three"
  bar => "beer"

  foo => "one"
  foo => "two"
  foo => "three"
  bar => "beer"

  $table->compress(APR::Const::OVERLAP_TABLES_MERGE);

  foo => "one, two, three"
  bar => "beer"

  $table_copy = $table->copy($p);

since: 2.0.00

Iterate over all the elements of the table, invoking provided subroutine for each element. The subroutine gets passed as argument, a key-value pair.

  $table->do(sub {...}, @filter);

ret: no return value

since: 2.0.00

Examples:

•

This filter simply prints out the key/value pairs and counts how many pairs did it see.

  use constant TABLE_SIZE => 20;
  our $filter_count;
  my $table = APR::Table::make($r->pool, TABLE_SIZE);

  # populate the table with ascii data
  for (1..TABLE_SIZE) {
      $table->set(chr($_+97), $_);
  }

  $filter_count = 0;
  $table->do("my_filter");
  print "Counted $filter_count elements";

  sub my_filter {
      my ($key, $value) = @_;
      warn "$key => $value\n";
      $filter_count++;
      return 1;
  }

Notice that CWmy_filter always returns 1, ensuring that CWdo() will pass all the key/value pairs.

•

This filter is similar to the one from the previous example, but this time it decides to abort the filtering after seeing half of the table, by returning 0 when this happens.

  sub my_filter {
      my ($key, $value) = @_;
      $filter_count++;
      return $filter_count == int(TABLE_SIZE)/2 ? 0 : 1;
  }

Get the value(s) associated with a given key. After this call, the data is still in the table.

  $val = $table->get($key);
  @val = $table->get($key);

since: 2.0.00

Make a new table.

  $table = APR::Table::make($p, $nelts);

since: 2.0.00

This table can only store text data. Add data to a table by merging the value with data that has already been stored using , as a separator:

  $table->merge($key, $val);

ret: no return value

since: 2.0.00

If the key is not found, then this function acts like CWCIadd()CW.

If there is more than one value for the same key, only the first (the oldest) value gets merged.

Examples:

•

Start with a pair:

  merge => "1"

and merge a to the value:

  $table->set(  merge => '1');
  $table->merge(merge => 'a');
  $val = $table->get('merge');

Result:

  $val == "1, a";

•

Start with a multivalued pair:

  merge => "1"
  merge => "2"

and merge a to the first value;

  $table->set(  merge => '1');
  $table->add(  merge => '2');
  $table->merge(merge => 'a');
  @val = $table->get('merge');

Result:

  $val[0] == "1, a";
  $val[1] == "2";

Only the first value for the same key is affected.

•

Have no entry and merge a;

  $table->merge(miss => 'a');
  $val = $table->get('miss');

Result:

  $val == "a";

For each key/value pair in CW$table_b, add the data to CW$table_a. The definition of CW$flags explains how CW$flags define the overlapping method.

  $table_a->overlap($table_b, $flags);

ret: no return value

since: 2.0.00

Access the constants via:

  use APR::Const -compile qw(:table);

or an explicit:

  use APR::Const -compile qw(OVERLAP_TABLES_SET OVERLAP_TABLES_MERGE);

This function is highly optimized, and uses less memory and CPU cycles than a function that just loops through table CW$table_b calling other functions.

Conceptually, CWoverlap() does this:

  apr_array_header_t *barr = apr_table_elts(b);
  apr_table_entry_t *belt = (apr_table_entry_t *)barr-E<gt>elts;
  int i;

  for (i = 0; i < barr->nelts; ++i) {
      if (flags & APR_OVERLAP_TABLES_MERGE) {
          apr_table_mergen(a, belt[i].key, belt[i].val);
      }
      else {
          apr_table_setn(a, belt[i].key, belt[i].val);
      }
  }

Except that it is more efficient (less space and cpu-time) especially when CW$table_b has many elements.

Notice the assumptions on the keys and values in CW$table_b they must be in an ancestor of CW$table_a's pool. In practice CW$table_b and CW$table_a are usually from the same pool.

Examples: Start with table CW$base:

  foo => "one"
  foo => "two"
  bar => "beer"

  foo => "three"

  use APR::Const    -compile => ':table';
  my $base = APR::Table::make($r->pool, TABLE_SIZE);
  my $add  = APR::Table::make($r->pool, TABLE_SIZE);

  $base->set(bar => 'beer');
  $base->set(foo => 'one');
  $base->add(foo => 'two');

  $add->set(foo => 'three');

  $base->overlap($add, APR::Const::OVERLAP_TABLES_SET);

  foo => "three"
  bar => "beer"

  foo => "one"
  foo => "two"

  foo => "three"
  bar => "beer"

  use APR::Const    -compile => ':table';
  my $base = APR::Table::make($r->pool, TABLE_SIZE);
  my $add  = APR::Table::make($r->pool, TABLE_SIZE);

  $base->set(foo => 'one');
  $base->add(foo => 'two');

  $add->set(foo => 'three');
  $add->set(bar => 'beer');

  $base->overlap($add, APR::Const::OVERLAP_TABLES_MERGE);

  foo => "one, two, three"
  bar => "beer"

  $table = $table_base->overlay($table_overlay, $p);

since: 2.0.00

Examples:

•

Start with table CW$base:

  foo => "one"
  foo => "two"
  bar => "beer"

and table CW$add:

  foo => "three"

which is done by:

  use APR::Const    -compile => ':table';
  my $base = APR::Table::make($r->pool, TABLE_SIZE);
  my $add  = APR::Table::make($r->pool, TABLE_SIZE);

  $base->set(bar => 'beer');
  $base->set(foo => 'one');
  $base->add(foo => 'two');

  $add->set(foo => 'three');

Now overlay using CWAPR::Const::OVERLAP_TABLES_SET:

  my $overlay = $base->overlay($add, APR::Const::OVERLAP_TABLES_SET);

That resulted in a new table CW$overlay (tables CWadd and CW$base are unmodified) which contains:

  foo => "one"
  foo => "two"
  foo => "three"
  bar => "beer"

Add a key/value pair to a table, if another element already exists with the same key, this will over-write the old data.

  $table->set($key, $val);

ret: no return value

since: 2.0.00

When adding data, this function makes a copy of both the key and the value. Remove data from the table.

  $table->unset($key);

ret: no return value

since: 2.0.00

CWAPR::Table also implements a tied interface, so you can work with the CW$table object as a hash reference.

The following tied-hash function are supported: CWFETCH, CWSTORE, CWDELETE, CWCLEAR, CWEXISTS, CWFIRSTKEY, CWNEXTKEY and CWDESTROY.

Note regarding the use of CWvalues(). CWAPR::Table can hold more than one key-value pair sharing the same key, so when using a table through the tied interface, the first entry found with the right key will be used, completely disregarding possible other entries with the same key. With Perl 5.8.0 and higher CWvalues() will correctly list values the corresponding to the list generated by CWkeys(). That doesn't work with Perl 5.6. Therefore to portably iterate over the key-value pairs, use CWeach() (which fully supports multivalued keys), or CWAPR::Table::do.

  $ret = $table->EXISTS($key);

since: 2.0.00

  $table->CLEAR();

ret: no return value

since: 2.0.00

  $table->STORE($key, $val);

ret: no return value

since: 2.0.00

  $table->DELETE($key);

ret: no return value

since: 2.0.00

  $ret = $table->FETCH($key);

since: 2.0.00

When iterating through the table's entries with CWeach(), CWFETCH will return the current value of a multivalued key. For example:

  $table->add("a" => 1);
  $table->add("b" => 2);
  $table->add("a" => 3);

  ($k, $v) = each %$table; # (a, 1)
  print $table->{a};       # prints 1

  ($k, $v) = each %$table; # (b, 2)
  print $table->{a};       # prints 1

  ($k, $v) = each %$table; # (a, 3)
  print $table->{a};       # prints 3 !!!

  ($k, $v) = each %$table; # (undef, undef)
  print $table->{a};       # prints 1

mod_perl 2.0 documentation.

mod_perl 2.0 and its core modules are copyrighted under The Apache Software License, Version 2.0.

The mod_perl development team and numerous contributors.