Apache2::Filter - Perl API for Apache 2.0 Filtering

  use Apache2::Filter ();

  # filter attributes
  my $c = $f->c;
  my $r = $f->r;
  my $frec = $f->frec();
  my $next_f = $f->next;

  my $ctx = $f->ctx;
  $f->ctx($ctx);

  # bucket brigade filtering API
  $rc = $f->next->get_brigade($bb, $mode, $block, $readbytes);
  $rc = $f->next->pass_brigade($bb);
  $rc = $f->fflush($bb);

  # streaming filtering API
  while ($filter->read(my $buffer, $wanted)) {
      # transform $buffer here
      $filter->print($buffer);
  }
  if ($f->seen_eos) {
      $filter->print("filter signature");
  }

  # filter manipulations
  $r->add_input_filter(\&callback);
  $c->add_input_filter(\&callback);
  $r->add_output_filter(\&callback);
  $c->add_output_filter(\&callback);
  $f->remove;

CWApache2::Filter provides Perl API for Apache 2.0 filtering framework.

Make sure to read CWthe Filtering tutorial|docs::2.0::user::handlers::filters.

The following methods can be called from any filter handler: Get the current connection object from a connection or a request filter:

  $c = $f->c;

since: 2.0.00

Get/set the filter context data.

  $ctx = $f->ctx;
         $f->ctx($ctx);

since: 2.0.00

A filter context is created before the filter is called for the first time and it's destroyed at the end of the request. The context is preserved between filter invocations of the same request. So if a filter needs to store some data between invocations it should use the filter context for that. The filter context is initialized with the CWundef value.

The CWctx method accepts a single SCALAR argument. Therefore if you want to store any other perl datastructure you should use a reference to it.

For example you can store a hash reference:

  $f->ctx({ foo => 'bar' });

and then access it:

  $foo = $f->ctx->{foo};

if you access the context more than once it's more efficient to copy it's value before using it:

  my $ctx = $f->ctx;
  $foo = $ctx->{foo};

to avoid redundant method calls. As of this writing CW$ctx is not a tied variable, so if you modify it need to store it at the end:

  $f->ctx($ctx);

META: later we might make it a TIEd-variable interface, so it'll be stored automatically.

Besides its primary purpose of storing context data across multiple filter invocations, this method is also useful when used as a flag. For example here is how to ensure that something happens only once during the filter's life:

  unless ($f->ctx) {
      do_something_once();
      $f->ctx(1);
  }

  $frec = $f->frec();

since: 2.0.00

For example you can call CW$frec->name to get filter's name. Return the CWApache2::Filter object of the next filter in chain.

  $next_f = $f->next;

since: 2.0.00

Since Apache inserts several core filters at the end of each chain, normally this method always returns an object. However if it's not a mod_perl filter handler, you can call only the following methods on it: CWget_brigade, CWpass_brigade, CWc, CWr, CWfrec and CWnext. If you call other methods the behavior is undefined.

The next filter can be a mod_perl one or not, it's easy to tell which one is that by calling CW$f->frec->name. Inside an HTTP request filter retrieve the current request object:

  $r = $f->r;

since: 2.0.00

If a sub-request adds filters, then that sub-request object is associated with the filter. Remove the current filter from the filter chain (for the current request or connection).

  $f->remove;

ret: no return value

since: 2.0.00

Notice that you should either complete the current filter invocation normally (by calling CWget_brigade or CWpass_brigade depending on the filter kind) or if nothing was done, return CWApache2::Const::DECLINED and mod_perl will take care of passing the current bucket brigade through unmodified to the next filter in chain.

Note: calling remove() on the very top connection filter doesn't affect the filter chain due to a bug in Apache 2.0 (which may be fixed in 2.1). So don't use it with connection filters, till it gets fixed in Apache and then make sure to require the minimum Apache version if you rely on.

Remember that if the connection is CW$c->keepalive ) and the connection filter is removed, it won't be added until the connection is closed. Which may happen after many HTTP requests. You may want to keep the filter in place and pass the data through unmodified, by returning CWApache2::Const::DECLINED. If you need to reset the whole or parts of the filter context between requests, use the technique based on CW$c->keepalives counting.

This method works for native Apache (non-mod_perl) filters too.

The following methods can be called from any filter, directly manipulating bucket brigades: Flush a bucket brigade down the filter stack.

  $rc = $f->fflush($bb);

since: 2.0.00

CWfflush is a shortcut method. So instead of doing:

  my $b = APR::Bucket::flush_create($f->c->bucket_alloc);
  $bb->insert_tail($b);
  $f->pass_brigade($bb);

one can just write:

  $f->fflush($bb);

  $rc = $next_f->get_brigade($bb, $mode, $block, $readbytes);
  $rc = $next_f->get_brigade($bb, $mode, $block);
  $rc = $next_f->get_brigade($bb, $mode)
  $rc = $next_f->get_brigade($bb);

  my $bb = APR::Brigade->new($c->pool, $c->bucket_alloc);

  $f->next->get_brigade($bb, $mode, $block, $readbytes);

since: 2.0.00

Available input filter modes (the optional second argument CW$mode) are: The filter should return at most readbytes data The filter should return at most one line of CRLF data. (If a potential line is too long or no CRLF is found, the filter may return partial data). The filter should implicitly eat any CRLF pairs that it sees. The filter read should be treated as speculative and any returned data should be stored for later retrieval in another mode. The filter read should be exhaustive and read until it can not read any more. Use this mode with extreme caution. The filter should initialize the connection if needed, NNTP or FTP over SSL for example.

Either compile all these constants with:

  use Apache2::Const -compile => qw(:input_mode);

But it's a bit more efficient to compile only those constants that you need.

Example:

Here is a fragment of a filter handler, that receives a bucket brigade from the upstream filter:

  use Apache2::Filter ();
  use APR::Const    -compile => qw(SUCCESS);
  use Apache2::Const -compile => qw(OK);
  sub filter {
      my ($f, $bb, $mode, $block, $readbytes) = @_;

      my $rc = $f->next->get_brigade($bb, $mode, $block, $readbytes);
      return $rc unless $rc == APR::Const::SUCCESS;

      # ... process $bb

      return Apache2::Const::OK;
  }

Usually arguments CW$mode, CW$block, CW$readbytes are the same as passed to the filter itself.

You can see that in case of a failure, the handler returns immediately with that failure code, which gets propagated to the downstream filter.

If you decide not check the return code, you can write it as:

  sub filter {
      my ($f, $bb, $mode, $block, $readbytes) = @_;

      $f->next->get_brigade($bb, $mode, $block, $readbytes);

      # ... process $bb

      return Apache2::Const::OK;
  }

and the error checking will be done on your behalf.

You will find many more examples in CWthe filter handlers|docs::2.0::user::handlers::filters and CWthe protocol handlers|docs::2.0::user::handlers::protocols tutorials. This is a method to use in bucket brigade output filters. It passes the current bucket brigade to the downstream output filter.

  $rc = $next_f->pass_brigade($bb);

since: 2.0.00

The caller relinquishes ownership of the brigade (i.e. it may get destroyed/overwritten/etc. by the callee).

Example:

Here is a fragment of a filter handler, that passes a bucket brigade to the downstream filter (after some potential processing of the buckets in the bucket brigade):

  use Apache2::Filter ();
  use APR::Const    -compile => qw(SUCCESS);
  use Apache2::Const -compile => qw(OK);
  sub filter {
      my ($f, $bb) = @_;

      # ... process $bb

      my $rc = $f->next->pass_brigade($bb);
      return $rc unless $rc == APR::Const::SUCCESS;

      return Apache2::Const::OK;
  }

The following methods can be called from any filter, which uses the simplified streaming functionality: Send the contents of CW$buffer to the next filter in chain (via internal buffer).

  $sent = $f->print($buffer);

since: 2.0.00

This method should be used only in streaming filters. Read data from the filter

  $read = $f->read($buffer, $wanted);

since: 2.0.00

Reads at most CW$wanted characters into CW$buffer. The returned value CW$read tells exactly how many were read, making it easy to use it in a while loop:

  while ($filter->read(my $buffer, $wanted)) {
      # transform $buffer here
      $filter->print($buffer);
  }

This is a streaming filter method, which acquires a single bucket brigade behind the scenes and reads data from all its buckets. Therefore it can only read from one bucket brigade per filter invocation.

If the EOS bucket is read, the CWseen_eos method will return a true value. This methods returns a true value when the EOS bucket is seen by the CWread method.

  $ok = $f->seen_eos;

since: 2.0.00

This method only works in streaming filters which exhaustively CW$f->read all the incoming data in a while loop, like so:

      while ($f->read(my $buffer, $wanted)) {
          # do something with $buffer
      }
      if ($f->seen_eos) {
          # do something
      }

The technique in this example is useful when a streaming filter wants to append something to the very end of data, or do something at the end of the last filter invocation. After the EOS bucket is read, the filter should expect not to be invoked again.

If an input streaming filter doesn't consume all data in the bucket brigade (or even in several bucket brigades), it has to generate the EOS event by itself. So when the filter is done it has to set the EOS flag:

  $f->seen_eos(1);

when the filter handler returns, internally mod_perl will take care of creating and sending the EOS bucket to the upstream input filter.

A similar logic may apply for output filters.

In most other cases you shouldn't set this flag. When this flag is prematurely set (before the real EOS bucket has arrived) in the current filter invocation, instead of invoking the filter again, mod_perl will create and send the EOS bucket to the next filter, ignoring any other bucket brigades that may have left to consume. As mentioned earlier this special behavior is useful in writing special tests that test abnormal situations.

Other methods which affect filters, but called on non-CWApache2::Filter objects: Add CW&callback filter handler to input request filter chain.

  $r->add_input_filter(\&callback);

Add CW&callback filter handler to input connection filter chain.

  $c->add_input_filter(\&callback);

ret: no return value

since: 2.0.00

[META: It seems that you can't add a filter when another filter is called. I've tried to add an output connection filter from the input connection filter when it was called for the first time. It didn't have any affect for the first request (over keepalive connection). The only way I succeeded to do that is from that input connection filter's filter_init handler. In fact it does work if there is any filter additional filter of the same kind configured from httpd.conf or via filter_init. It looks like there is a bug in httpd, where it doesn't prepare the chain of 3rd party filter if none were inserted before the first filter was called.] Add CW&callback filter handler to output request filter chain.

  $r->add_output_filter(\&callback);

Add CW&callback filter handler to output connection filter chain.

  $c->add_output_filter(\&callback);

ret: no return value

since: 2.0.00

Packages using filter attributes have to subclass CWApache2::Filter:

  package MyApache2::FilterCool;
  use base qw(Apache2::Filter);

Attributes are parsed during the code compilation, by the function CWMODIFY_CODE_ATTRIBUTES, inherited from the CWApache2::Filter package. The CWFilterRequestHandler attribute tells mod_perl to insert the filter into an HTTP request filter chain.

For example, to configure an output request filter handler, use the CWFilterRequestHandler attribute in the handler subroutine's declaration:

  package MyApache2::FilterOutputReq;
  sub handler : FilterRequestHandler { ... }

and add the configuration entry:

  PerlOutputFilterHandler MyApache2::FilterOutputReq

This is the default mode. So if you are writing an HTTP request filter, you don't have to specify this attribute.

The section HTTP Request vs. Connection Filters delves into more details. The CWFilterConnectionHandler attribute tells mod_perl to insert this filter into a connection filter chain.

For example, to configure an output connection filter handler, use the CWFilterConnectionHandler attribute in the handler subroutine's declaration:

  package MyApache2::FilterOutputCon;
  sub handler : FilterConnectionHandler { ... }

and add the configuration entry:

  PerlOutputFilterHandler MyApache2::FilterOutputCon

The section HTTP Request vs. Connection Filters delves into more details. The attribute CWFilterInitHandler marks the function suitable to be used as a filter initialization callback, which is called immediately after a filter is inserted to the filter chain and before it's actually called.

  sub init : FilterInitHandler {
      my $f = shift;
      #...
      return Apache2::Const::OK;
  }

In order to hook this filter callback, the real filter has to assign this callback using the CWFilterHasInitHandler which accepts a reference to the callback function.

For further discussion and examples refer to the Filter Initialization Phase tutorial section. If a filter wants to run an initialization callback it can register such using the CWFilterHasInitHandler attribute. Similar to CWpush_handlers the callback reference is expected, rather than a callback name. The used callback function has to have the CWFilterInitHandler attribute. For example:

  package MyApache2::FilterBar;
  use base qw(Apache2::Filter);
  sub init   : FilterInitHandler { ... }
  sub filter : FilterRequestHandler FilterHasInitHandler(\&init) {
      my ($f, $bb) = @_;
      # ...
      return Apache2::Const::OK;
  }

For further discussion and examples refer to the Filter Initialization Phase tutorial section.

mod_perl 2.0 filters configuration is explained in the filter handlers tutorial. See CWPerlInputFilterHandler. See CWPerlOutputFilterHandler. See CWPerlSetInputFilter. See CWPerlSetInputFilter.

CWApache2::Filter also implements a tied interface, so you can work with the CW$f object as a hash reference.

The TIE interface is mostly unimplemented and might be implemented post 2.0 release.

  $ret = TIEHANDLE($stashsv, $sv);

since: subject to change

  $ret = PRINT(...);

since: subject to change

mod_perl 2.0 documentation.

mod_perl 2.0 and its core modules are copyrighted under The Apache Software License, Version 2.0.

The mod_perl development team and numerous contributors.