HTML::TokeParser::Simple - Easy to use CWHTML::TokeParser interface

 use HTML::TokeParser::Simple;
 my $p = HTML::TokeParser::Simple->new( $somefile );

 while ( my $token = $p->get_token ) {
     # This prints all text in an HTML doc (i.e., it strips the HTML)
     next unless $token->is_text;
     print $token->as_is;
 }

CWHTML::TokeParser is an excellent module that's often used for parsing HTML. However, the tokens returned are not exactly intuitive to parse:

 ["S",  $tag, $attr, $attrseq, $text]
 ["E",  $tag, $text]
 ["T",  $text, $is_data]
 ["C",  $text]
 ["D",  $text]
 ["PI", $token0, $text]

To simplify this, CWHTML::TokeParser::Simple allows the user ask more intuitive (read: more self-documenting) questions about the tokens returned.

You can also rebuild some tags on the fly. Frequently, the attributes associated with start tags need to be altered, added to, or deleted. This functionality is built in.

Since this is a subclass of CWHTML::TokeParser, all CWHTML::TokeParser methods are available. To truly appreciate the power of this module, please read the documentation for CWHTML::TokeParser and CWHTML::Parser.

The constructor for CWHTML::TokeParser::Simple can be used just like CWHTML::TokeParser's constructor:

  my $parser = HTML::TokeParser::Simple->new($filename);
  # or
  my $parser = HTML::TokeParser::Simple->new($filehandle);
  # or
  my $parser = HTML::TokeParser::Simple->new(\$html_string);

  my $parser = HTML::TokeParser::Simple->new(file   => $filename);
  # or
  my $parser = HTML::TokeParser::Simple->new(handle => $filehandle);
  # or
  my $parser = HTML::TokeParser::Simple->new(string => $html_string);

Note that you do not have to provide a reference for the string if using the string constructor.

As a convenience, you can also attempt to fetch the HTML directly from a URL.

  my $parser = HTML::TokeParser::Simple->new(url => 'http://some.url');

This method relies on CWLWP::Simple. If this module is not found or the page cannot be fetched, the constructor will CWcroak().

These accessors return true or false. Use this to determine if you have any tag. An optional tag type may be passed. This will allow you to match if it's a particular tag. The supplied tag is case-insensitive.

 if ( $token->is_tag ) { ... }

 if ( $token->is_start_tag ) { ... }
 if ( $token->is_start_tag( 'font' ) ) { ... }

 if ( $token->is_start_tag( qr/^h[123456]$/ ) ) { ... }

 while ( $token = $p->get_token ) {
   if ( $token->is_end_tag( 'form' ) ) { ... }
 }

 while ( $token = $p->get_token ) {
   if ( $token->is_end_tag( '/form' ) ) { ... }
 }

Some of these were originally CWreturn_ methods, but that name was not only unwieldy, but also went against reasonable conventions. The CWget_ methods listed below still have CWreturn_ methods available for backwards compatibility reasons, but they merely call their CWget_ counterpart. For example, calling CWreturn_tag() actually calls CWget_tag() internally. Do you have a start tag or end tag? This will return the type (lower case). If you have a start tag, this will return a hash ref with the attribute names as keys and the values as the values. If you pass in an attribute name, it will return the value for just that attribute. Returns false if the token is not a start tag. For a start tag, this is an array reference with the sequence of the attributes, if any. Returns false if the token is not a start tag. This method has been heavily deprecated (for a couple of years) in favor of CWas_is. Programmers were getting confused over the difference between CWis_text, CWreturn_text, and some parser methods such as CWHTML::TokeParser::get_text and friends. Using this method still succeeds, but will now carp and will be removed in the next major release of this module. This is the exact text of whatever the token is representing. For processing instructions, this will return the token found immediately after the opening tag. Example: For <?php, php will be the start of the returned string. Note that process instruction handling appears to be incomplete in CWHTML::TokeParser. Returns false if the token is not a process instruction.

The CWdelete_attr() and CWset_attr() methods allow the programmer to rewrite start tag attributes on the fly. It should be noted that bad HTML will be corrected by this. Specifically, the new tag will have all attributes lower-cased with the values properly quoted.

Self-closing tags (e.g. <hr />) are also handled correctly. Some older browsers require a space prior to the final slash in a self-closed tag. If such a space is detected in the original HTML, it will be preserved.

Calling a mutator on an token type that does not support that property is a no-op. For example:

 if ($token->is_comment) {
    $token->set_attr(foo => 'bar'); # does nothing
 }

 # <body bgcolor="#FFFFFF">
 $token->delete_attr('bgcolor');
 print $token->as_is;
 # <body>

 # <p>
 $token->set_attr(class => 'some_class');
 print $token->as_is;
 # <p class="some_class">

 # <body bgcolor="#FFFFFF">
 $token->set_attr('bgcolor','red');
 print $token->as_is;
 # <body bgcolor="red">

  $tag->set_attr($tag->get_attr);

  my $attrs = {
    class  => 'headline',
    valign => 'top'
  };
  $token->set_attr($attrs) 
    if $token->is_start_tag('td') &&  $token->get_attr('class') eq 'stories';

 # <body alink=#0000ff BGCOLOR=#ffffff class='none'>
 $token->rewrite_tag;
 print $token->as_is;
 # <body alink="#0000ff" bgcolor="#ffffff" class="none">

 my $parser = HTML::TokeParser::Simple->new( string => $ugly_html );
 while (my $token = $parser->get_token) {
     $token->rewrite_tag;
     print $token->as_is;
 }

The parser returns tokens that are blessed into appropriate classes. Some people get confused and try to call parser methods on tokens and token methods on the parser. To prevent this, CWHTML::TokeParser::Simple versions 1.4 and above now bless all tokens into appropriate token classes. Please keep this in mind while using this module (and many thanks to PodMaster <http://www.perlmonks.org/index.pl?node_id=107642> for pointing out this issue to me.)

For some strange reason, your Pointy-Haired Boss (PHB) is convinced that the graphics department is making fun of him by embedding rude things about him in HTML comments. You need to get all HTML comments from the HTML.

 use strict;
 use HTML::TokeParser::Simple;

 my @html_docs = glob( "*.html" );

 open PHB, "> phbreport.txt" or die "Cannot open phbreport for writing: $!";

 foreach my $doc ( @html_docs ) {
     print "Processing $doc\n";
     my $p = HTML::TokeParser::Simple->new( file => $doc );
     while ( my $token = $p->get_token ) {
         next unless $token->is_comment;
         print PHB $token->as_is, "\n";
     }
 }

 close PHB;

Uh oh. Turns out that your PHB was right for a change. Many of the comments in the HTML weren't very polite. Since your entire graphics department was just fired, it falls on you need to strip those comments from the HTML.

 use strict;
 use HTML::TokeParser::Simple;

 my $new_folder = 'no_comment/';
 my @html_docs  = glob( "*.html" );

 foreach my $doc ( @html_docs ) {
     print "Processing $doc\n";
     my $new_file = "$new_folder$doc";

     open PHB, "> $new_file" or die "Cannot open $new_file for writing: $!";

     my $p = HTML::TokeParser::Simple->new( $file => doc );
     while ( my $token = $p->get_token ) {
         next if $token->is_comment;
         print PHB $token->as_is;
     }
     close PHB;
 }

Your company was foo.com and now is bar.com. Unfortunately, whoever wrote your HTML decided to hardcode http://www.foo.com/ into the CWaction attribute of the form tags. You need to change it to http://www.bar.com/.

 use strict;
 use HTML::TokeParser::Simple;

 my $new_folder = 'new_html/';
 my @html_docs  = glob( "*.html" );

 foreach my $doc ( @html_docs ) {
     print "Processing $doc\n";
     my $new_file = "$new_folder$doc";

     open FILE, "> $new_file" or die "Cannot open $new_file for writing: $!";

     my $p = HTML::TokeParser::Simple->new( file => $doc );
     while ( my $token = $p->get_token ) {
         if ( $token->is_start_tag('form') ) {
             my $action = $token->get_attr(action);
             $action =~ s/www\.foo\.com/www.bar.com/;
             $token->set_attr('action', $action);
         }
         print FILE $token->as_is;
     }
     close FILE;
 }

For compatability reasons with CWHTML::TokeParser, methods that return references are violating encapsulation and altering the references directly will alter the state of the object. Subsequent calls to CWrewrite_tag() can thus have unexpected results. Do not alter these references directly unless you are following behavior described in these docs. In the future, certain methods such as CWget_attr, CWget_attrseq and others may return a copy of the reference rather than the original reference. This behavior has not yet been changed in order to maintain compatability with previous versions of this module. At the present time, your author is not aware of anyone taking advantage of this feature, but it's better to be safe than sorry.

Use of CW$HTML::Parser::VERSION which is less than 3.25 may result in incorrect behavior as older versions do not always handle XHTML correctly. It is the programmer's responsibility to verify that the behavior of this code matches the programmer's needs.

Note that CWHTML::Parser processes text in 512 byte chunks. This sometimes will cause strange behavior and cause text to be broken into more than one token. You can suppress this behavior with the following command:

 $p->unbroken_text( [$bool] );

See the CWHTML::Parser documentation and http://www.perlmonks.org/index.pl?node_id=230667 for more information.

There are no known bugs, but that's no guarantee.

Address bug reports and comments to: <eop_divo_sitruc@yahoo.com>. When sending bug reports, please provide the version of CWHTML::Parser, CWHTML::TokeParser, CWHTML::TokeParser::Simple, the version of Perl, and the version of the operating system you are using.

Reverse the name to email the author.

You may wish to change the behavior of this module. You probably do not want to subclass CWHTML::TokeParser::Simple. Instead, you'll want to subclass one of the token classes. CWHTML::TokeParser::Simple::Token is the base class for all tokens. Global behavioral changes should go there. Otherwise, see the appropriate token class for the behavior you wish to alter.

HTML::TokeParser::Simple::Token

HTML::TokeParser::Simple::Token::Tag

HTML::TokeParser::Simple::Token::Text

HTML::TokeParser::Simple::Token::Comment

HTML::TokeParser::Simple::Token::Declaration

HTML::TokeParser::Simple::Token::ProcessInstruction

Copyright (c) 2004 by Curtis Ovid Poe. All rights reserved. This program is free software; you may redistribute it and/or modify it under the same terms as Perl itself

Curtis Ovid Poe <eop_divo_sitruc@yahoo.com>

Reverse the name to email the author.